Bedroom

Cloaked

First Past The PostBy Roger Firth, adapted to Gruescript by Robin Johnson

For instructions, click:

I am standing in my rather untidy bedroom. Junk lies strewn 'tidily' on the desk in my unique filing system. Other things like a bed and cupboards can be vaguely seen underneath the mounds of rubbish. The bedroom door leads out to the south.

Exits:

Actions:

You can also see:

junk
golfbag

Really restart this game?

Display options

font:

font size:

Print room title in scroller:

Always

Landscape only

Never

List objects in scroller

Always

Landscape only

Never

This game was made with gruescript.

# '#' means this line (or the rest of this line) is a comment
# (if you want to output '#' during your game, use "&num;")
game First Past The Post# Game title
id CLOD # game ID (used to identify cookies; should be unique on your site)
author Roger Firth, adapted to Gruescript by Robin Johnson
version 0.0.1
person 2 # 2nd person, i.e. "You are in..."
examine off # if 'on', the verb 'examine' will be implemented by clicking nouns
status { $Room } | { $cloaked } # '|' divides left and right ends of status bar

# setting "cloaked" will set the status bar
var cloaked Cloaked
rule
assign cloaked Cloaked
!has cloak worn
assign cloaked Uncloaked

setverb put_inside_golfbag
has $this portable
carried $this
has golfbag worn
!eq $this golfbag

verb put_inside_golfbag
assign golfbag.contents multiple
assign $this.contained_in golfbag
hide $this
say You put the {$this} inside the golfbag.

thing golfbag
loc bedroom
tags container portable wearable
verbs examine

setverb unlock
has $this locked
!eq $held 0
has $held key

verb unlock
eq $held.locktype $this.locktype: {The $held} doesn't fit the lock on {the $this}. # message prints if assertion fails
untag $this locked: {The $held} turns anticlockwise in the lock. # message always prints
tag $this unlocked

setverb search
hasall $this container

verb search
has $this container
eq $this.contents multiple: You find nothing!
say You find something!
assign $this.contents 0
assign container $this
all things
    eq $this.contained_in $container
    bring $this
    assign $this.contained_in 0

# a room
room bedroom I am standing in my rather untidy bedroom. Junk lies strewn 'tidily' on the desk in my unique filing system. Other things like a bed and cupboards can be vaguely seen underneath the mounds of rubbish. The bedroom door leads out to the south. # internal name and description
tags start # the player starts here
south landing # directions to other rooms
verbs magic

verb magic
give tape
give rock_cake
goto skylight

verb search junk
at bedroom
say I move some of the rubbish to one side and find some sticky tape and some scissors.
bring tape
bring scissors
hide junk

thing tape sticky tape
tags portable

thing junk
loc bedroom
verbs search

thing scissors
tags portable

room landing I am standing on the landing. This basically consists of a small strip of carpeted floor. The only really interestig things about this room are the doors which lie to the east, west, north and northeast. The hall is visible, down some stairs.
north bedroom
west spareroom
northeast parentsroom
east bathroom
down hallway

room spareroom This is the spare room. It is reserved for the use of visitors! However, no one ever seems to come to stay and it's been long disused, and now it's virtually empty. Even the creaky old bed has gone, meaning that only a battered old cupboard remains. The landing is to the east.
east landing

thing cupboard
loc spareroom
verbs search

setverb oil cupboard
carried oil
!has cupboard oiled

verb oil cupboard
tag cupboard oiled
say I oil the rusty hinges and the door now opens freely.

verb search cupboard
at spareroom
has cupboard oiled: I can't - the cupboard door won't open as the hinges are rusty!
say I open up the door and root about inside. I find an old golfbag...
bring golfbag
hide cupboard

verb examine golfbag
say The golfbag is sort of oblong-shaped and was once brightly coloured but sadly the material fades so it's now a dull grey.

room parentsroom I am in my parents' room. It is a striking contrast to my own rather dirty 'sleeping quarters' and is actually the only tidy room in the the house due to the fact that it's the one my mum cleans even when it's Dad's turn to clean up. Everything appears to have it's own little resting place in the room and even the polished cupboard and table seem to stand to attention. The door leads southwest.
southwest landing

thing table
loc parentsroom
tags container
prop contents multiple

thing makeup make-up 
tags portable wearable
prop contained_in table

verb remove makeup
!carried toilet_roll
say Easier said than done!

verb remove makeup
carried toilet_roll
say I wipe off the disgusting make-up with some toilet tissue.
hide makeup

thing nailfile
tags portable
prop contained_in table

thing polished_cupboard
loc parentsroom
tags container
prop contents multiple

thing dress
tags wearable portable
prop contained_in polished_cupboard

thing shoes
tags plural portable wearable
prop contained_in polished_cupboard

thing bed
loc parentsroom
verbs look_under
tags scales

verb look_under bed
at parentsroom
has bed scales: "Nope, there's nothing here."
say "Nope, there's nothing here. Wait a minute, I've found some bathroom scales. What are they doing here?..."
bring scales
untag bed scales

thing scales
tags portable
verbs stand_on

verb stand_on scales
random x 2
!eq $x 1: The scales say, "one at a time please!"
!eq $x 2: The scales say, "Please note, this is a no parking area!"

room bathroom This is the bathroom. There's not much room in here! The cramped confines make it possible to not only go to the loo but also wash my hands in the skin and my feet in the bath at the same time. The landing is a small step away to the west.
west landing

thing toilet_roll
loc bathroom
tags portable

room hallway A white mat covers the floor of the small room dubbed as 'hallway'. Doorways lead both east and west, while to the south is the main door and some stairs lead upwards to the landing.
up landing
east living_room
west kitchen
south doorstep

room doorstep I am on the doorstep of the house. The main door is in front of me, to the north. Beside the door is a small brass plaque which reads, "54 Tinderbox Gardens, Residence of the 'Spludges'". The the south is the front garden.
north hallway
south front_garden

room front_garden The front garden is in an even worse state than the back one. Weeds and overgrown grass spring up everywhere. Basically we've found that the easiest way to stop the neighbours complaining is to tell them we've started a 'nature garden' to preserve 'England's natural wildlife'. To the south, through the gate, lies the main road.
north doorstep
south main_road

room main_road This is "Tinderbox Gardens", a suitably inapt name given to a road that resembles the M52. Most of the passing traffic here seems to be minus one important feature that manufacturers usually add to cars - brakes! THis does nothing to alter the fact that to the north lies the garden while to the east is a bus-stop. 
north front_garden
east bus_stop

thing dog
loc main_road
prop display large dog

rule
at main_road
here dog
say A large dog is sitting on the kerb here.

verb go east
at main_road
here dog
say The dog won't let you pass.

verb throw plate
carried plate
here dog
say I throw the plate off to the west and the dog, thinking it to be a frisby, chases after it...
hide dog
hide plate

verb go east
at main_road
thingat guitar bus_stop 
say As I walk down the street I pass a bearded man strumming his guitar.
say "This is the road to hell!" he sings.
say "Nah, mate.", I tell him, "This is Tinderbox Gardens."
say "Drat!" he says, "I must have taken the wrong flippin' turning off the motorway." He stalks off angrily...
hide guitar
goto bus_stop

thing guitar
loc bus_stop
prop display man with guitar

room bus_stop I now find myself at the bus-stop and I make passing conversation, such as "Do you come here often?". The lamp-post I'm talking to seems unimpressed by my conversational skills and so I restrict myself to waiting for a bus.
west main_road

thing lamp_post
loc bus_stop
verbs examine

verb examine lamp_post
say Up the lamp-post I can see a man. He is singing a George Formby song! Strange!
say "Hello there!" I say and he replies, "Hello, comrade."
say "Who are you?" I ask.
say "I am a very great soviet leader!" he says.
say Oh! Now I see - He's Lenin on a lamp-post at the corner of the street!

verb wait
at bus_stop
say I wait for a while...
say
say ...and pretty soon the bus turns up!
bring bus

thing bus
verbs board

verb board bus
run board_bus
say My disguise as an OAP is perfect and the bus driver suspects nothing as I hand him my tokens...
say
say I sit on the bus for a while before getting off at the next stop...
say
goto post_office

proc board_bus
!has dress worn 
!has shoes worn
!has makeup worn
!has tights worn
say My disguise is not quite right and the driver sees through it.
say "Hey Ernie," he says as he pushes me off the bus. "Wait till I tell the lads down the pub about this!". I go home and die of embarrassment...
die Game Over!

thing mat
loc hallway
verbs examine
tags uncut

verb examine mat
say It is a small white fluffy mat and it's firmly affixed to the floor. My mum's fed up with it moving all the time when we walked through!

setverb cut mat
carried scissors
has mat uncut

verb cut mat
say I cut a small square piece of material from the mat
bring fluffy_material
untag mat uncut

thing fluffy_material
tags portable wearable examine

verb examine fluffy_material
say It is a small, roundish piece of white rug.

room living_room This is the living room. From the state of things you would be excused if you wondered just exactly what had been living in here - a pig or an elephant perhaps? This unusual state is due entirely due to the fact that it's my fathers 'turn' to clean the house this week. A dirty old sofa and a battered TV set are the only objects worth mentioning in the room.
west landing

thing sofa
loc living_room
tags container
prop contents multiple

thing handbag
tags portable
prop contained_in sofa

verb take handbag
say As I grab hold of it, and old voice croaks, "Leave that alone, Ernie!". The wrinkled person that enters is one other than my Nan, who must have come to get her handbag.
say "You don't look well!" she informs me, "It's too much chocolate, you know!".
say "More like too much of mum's cooking!" I think to myself.
say My nan grabs her handbag and leaves the room, pausing only to hit me with the aforementioned bag.
say "Don't let me catch you messing about with my bag again." She says, "You're not too old to get a smacked bottom, you know!"
say I watch her leave. Now, was it my imagination, or did I see something drop out of her bag?..."
hide handbag
bring bus_tokens

thing bus_tokens
tags mass_noun portable

room kitchen This is the luxury kitchen of the house. When I say 'luxury' I mean that it has a sink, a sideboard and not much else. The faint smell of burning indicates my mum's been trying to cook again. The hall lies to the east while the back door leads out to the west. A small sign hangs above the oven.
east hallway
west garden

thing sink
loc kitchen
tags container
prop contents multiple

thing plate
tags portable
prop contained_in sink
cverbs examine throw

verb examine plate
say Because of my family's low budget, what would usually be a bone chine plate is a paper 'party' one.

thing sign
loc kitchen
verbs read

verb read sign
say It reads, "If you can't smell burning - we're having salad for dinner!"

thing oven
tags container
prop contents multiple

thing rock_cake
tags portable
prop contained_in oven

thing sideboard
loc kitchen
tags container
prop contents multiple

thing match
tags portable
prop contained_in sideboard

room garden I am standing in the rather small confines of our back garden. A large gnome sits ammidst the various glowers which lie dead on their backs. To the west stands an old shack which may not look much to you but it's 'shed' to me. The main house is to the east.
east kitchen
west inside_shed

verb go west
at garden
has shed locked
say The shed door is locked!

thing gnome
loc garden
verbs examine
tags hat

verb examine gnome
has gnome hat: The gnome is the ugliest thing I'd seen until I ran into Gareth Pitchford at the 'Probe' convention. It has a huge nose. I call it 'Ingrid' for obvious reasons!
say The gnome is the ugliest thing I'd seen until I ran into Gareth Pitchford at the 'Probe' convention. It has a huge nose and is wearing a red hat. I call it 'Ingrid' for obvious reasons!
bring hat
bring nose
untag gnome hat

thing nose Gnome's nose
verbs push

verb push nose
say I press the Gnome's nose and it's mouth opens.
hide nose
bring mouth

thing mouth Gnome's mouth
verbs examine

thing hat
tags portable wearable

verb examine mouth
say You look inside the Gnome's mouth and find a key.
bring key
hide mouth

thing key a small key
tags portable key
prop locktype shed

thing shed
loc garden
verbs examine
tags lockable locked
prop locktype shed

verb examine shed
say It is badly built, but the door looks solid enough.

room inside_shed This is the shed. How the walls manage to stay upright I do not know, as they give the impression of staggering under the weight of the roof. A battered old bench lies against one of the walls. The door is to the east.
east garden
prop display Inside Shed

thing wall
loc inside_shed
verbs examine
tags onions

verb examine wall
has wall onions
say Hanging up on the wall I find some onions in a pair of tights...
bring onions
untag wall onions

thing onions some tights filled with onions!
tags portable plural
verbs remove_onions

verb remove_onions onions
say I take the onions out of the tights.
hide onions
carry tights
carry some_onions

thing tights a pair of tights
tags portable plural wearable

thing some_onions
tags portable plural

thing bench
loc inside_shed
verbs examine search
tags oil string

setverb pull bench
has bench string

verb examine bench
say It is made of wood and is severly rotted away in places.

verb search bench
has bench oil
say Searching round on the bench I find a small can of oil...
bring oil
untag bench oil

thing oil an oil can
tags portable

verb pull bench
say I pull the bench away from the wall. Behind it, I find a small ball of string...
bring string
untag bench string

thing string A ball of string
tags portable

room post_office I stand outside the entrance to 'Scumsville General Post sorting Office'. It's bleak grey walls would form a blot on the landscape in any other town but all the buildings in Scumsville are like this. The main door lies to the east.
east sorting_office

verb go east
at post_office
say A sign on the door says, "Sorry. Nobody allowed in sorting office today!"

thing grey_walls
loc post_office
verbs examine

verb examine grey_walls
say A drain-pipe comes down from the roof here.
bring drain_pipe

thing drain_pipe
verbs climb

verb climb drain_pipe
has shoes worn
say Somehow I don't think high-heeled shoes were designed for climbing drain-pipes!

verb climb drain_pipe
carried golfbag
tag golfbag shoulder
run dropall
say I sling the golfbag over my shoulder, and climb up the drain-pipe and onto the roof...
say
goto roof

verb climb drain_pipe
!has golfbag shoulder
run dropall
goto roof

proc dropall
say In order to climb the drain pipe I must drop any items that I'm carrying.
say
all carried
put $this post_office

room roof I am standing on the roof of the sorting office. It has got to be the most imaginatively painted rood in 'Scumsville', though the creators are the many birds which fly above. The roof slopes down to the east.
down post_office
east skylight

rule
at roof
has golfbag shoulder
wear golfbag
untag golfbag shoulder

verb down
at roof
say You see how far up you are, so decide not to!

room skylight A skylight set in the roof here, provides some light to the sorting office below.
west roof

thing sky_light
loc skylight
verb examine

verb examine sky_light
say It is firmly closd from the inside. Below it, I can see the floor of the sorting office which has several mailsacks piled on it.

setverb stick_to_skylight tape
carried tape
at skylight

verb stick_to_skylight tape
say I cunningly 'tape' the window
hide tape
tag skylight taped

setverb smash_skylight rock_cake
at skylight
carried rock_cake
has skylight taped

verb smash_skylight rock_cake
say Due to my amazingly brilliant idea of window 'taping' the glass doesn't fly everywhere and makes hardly any noise...
tag skylight broken
write skylight.desc A skylight set in the roof here, provides some light to the sorting office below. Some vandal has smashed the skylight.
open skylight down small_room

verb go down
at skylight
say
say I jump onto the mailsacks and they break my fall... but not my legs!
say
goto small_room

room small_room This small room is filled with mailsacks. To the east lies the main part of the sorting office which is not for 'unauthorised peronnel', according to the sigbn. There's also a skylight in the roof here, while to the south and west there are doors.
south locker_room
east sorting_room

thing mailsacks
loc small_room
tags plural
verbs examine

verb examine mailsacks
say As they say 'Royal Mail' on them, they're probably filled with mail.

setverb cut mailsacks
carried scissors

verb cut mailsacks
say I cut open the mailsack with the scissors.
tag mailsacks cut

setverb search mailsacks
has mailsacks cut

verb search mailsacks
say I search in the mailsack and find a letter that jingles.
bring envelope
hide mailsacks

thing envelope
tags portable
cverbs open

verb open envelope 
say Inside the envelope I find a letter and some loose cash
hide enveloper
give letter
give loose_cash

thing letter
tags portable
cverbs read

thing loose_cash
tags plural portable

verb read letter
say It's a short note which reads,
say "I don't know why everyone says it's not safe to send money through the post! It's not as if some nosey adventurer's going to nab it, is it?

verb examine loose_cash
say It's about 3 pounds in loose cash. I don't know, will people ever learn it's not safe to send money through the post?

room locker_room I am in the staff locker room. The room is not suprisingly full of lockers. The exit lies to the north.
north small_room

thing locker
verbs examine

verb examine locker
say The one nearest to me is marked 'Property of David Jones'.

setverb pick_lock nailfile
carried nailfile

verb pick_lock locker
say I unlock and open the locker.
tag locker open

setverb search locker
has locker open

verb search locker
say In the locker I find a postman's uniform.
bring a_postmans_uniform
hide locker

thing a_postmans_uniform
tags portable wearable

room sorting_room This is the main sorting room of the 'Scumsville' post office. Around me I can see various snals diligently, if rather slowly, sorting through all the mail. So that's why it takes so long! Exits lie to the east and west.
west small_room
east back_door

rule
at sorting_room
!has a_postmans_uniform worn
say
say
say One of the snails moves with lightning speed to throw me out, because members of the public are not allowed in the sorting office. It's 'snails only' territory!...
say
goto post_office

rule
at sorting_room
has a_postmans_uniform worn
say
say I glance at the pigeon holes that the snails are stuffing envelopes in. Each road has its own hole and I glance along the names looking for Crabworth stret, the road where Rosie lives. I find it quite easily but (horror of horrors!), it's empty - the postman must have already started on his round!

room back_door I am at the back door of the sorting office. It leads out to a yard to the east. The main part of the office is back to the west.
west sorting_room
east small_yard

room small_yard I am in a small yard behind the post office. There is a small boy playing around on his bike. I can go west, back into the sorting office, or east out of the back gate.
west back_door
east road

verb go east
at small_yard
say There's no way I can get to Crabworth Street in time if i walk!

thing bike
loc small_yard
tags portable
verbs ride

verb take bike
here boy
say The boy says, "Geroff my bike!"

thing boy
tags male
loc small_yard

setverb hire bike
held loose_cash

verb hire bike
say Though not being the greatest conversationalist, the boy understands the importance of money and lets me hire the bike he was playing with.
say "You can keep it!" he says.
say "Thanks." I say.
say "That's alright. I nicked it anyway!"...
hide boy

verb ride bike
say Off I pedal until I reach the street where Rosie lives.
say Discarding the bike, I walk along the road...
hide bike
say
goto crabworth_Street

room crabworth_street This is 'Crabworth Stret', the home of my beloved Rosie. The road continues east.
east various_houses

thing postman
tags male
loc crabworth_street

room various_houses Various houses are dotted about here in 'Crabworth Street'. They're not much to look at, but the nothing is in 'Scumsville'!
west crabworth_street
east mansion

room mansion At this point on 'Crabworth Street' I can see a huge, mansion-like house, to the north.
west various_houses
east lamp_posts
north mansion_garden

room mansion_garden I am in the garden of a large house. To my right is a small gate, behind which is a large, snarling dog. While behind is the main gate.
south mansion

thing gate
loc mansion_garden
verbs open close
tags closed

verb close gate
has gate closed
say The gate is already closed!

verb open gate
has gate closed
say The dog rushes out, snarling madly.
bring mad_dog
hide gate

thing mad_dog
tags male

room lamp_posts Two lamp-posts provide dim light here in the street on this cold, bleak morning. They might, of course, provide some more light if they had bulbs in! To the east and west the road continues.
west mansion
east rosies_house

room rosies_house I am outside my beloved Rosie's house, which lies to the north. The road looks almost attractive, with all it's green bushes and shrubs. The road stops here, but I can go back to the west if I wish.
west lamp_posts
north inside_rosies

verb go north
at rosies_house
say I can't face Rosie yet! I haven't completed my quest!